Sistema Jorditron 2.0

system "Jorditron 2.00"
{
Segundo Intento

-es compacto
-analiza Docena, Columna, Calles, Lineas y Cuadros y es simple agregar nuevos layouys

-se fija hace cuanto que no sale cada (Docena/Columna/Calle/Linea/Cuadro) y
cuando hay uno de estos que no sale hace cierta cantidad de bolas (12/12/48/24/36)
comienza su propia progresion.

-lo interesante del programa es que las progresiones son individuales,
es decir, si hay un cuadro que no sale hace 36 bolas, comienza a apostarse
con la progresion para cuadros, y si al mismo tiempo hay una docena que no sale hace 12 bolas
comienza a apostarse al mismo tiempo con la progresion respectiva a las docenas.

-las progresiones son al estilo martingala normal,
es decir siempre intentando recuperar y ganar al menos una ficha
esto creo q es el punto de fallo del programa, ya todos conocemos las
fallas de la martingala.

en la proxima version tendra:
-un analisis de Bankroll, (plata inicial)
-prevencion ante catastrofes
-analizara Zonas de la rueda
-Analizara lo que llamo Triada.. pueden consultarme al respecto

Por favor haganme saber los problemas y ayuden con mejoras
Ojala pueda servirles
}
method "main"
begin
While Starting a New Session
begin
//Aqui seteo todas las progresiones,contadores y Layouts

// Para Docenas y Columnas
set list [1,1,2,3,4,6,9,14,21,31,47,70,105,158,237]
to record "ProgDocCol" data ;
set list [1,1,1] to record "ContDocena" data;
set list [1,1,1] to record "ContColumna" data;
copy list [1st dozen,2nd dozen,3rd dozen]
to record "TodasDocenas" layout;
copy list [Column A,Column B,Column C] to record "TodasColumnas" layout;

// Para Calles
set list [1,1,1,1,1,1,1,1,1,1,1,2,2,2,2,2,2,3,3,3,3,4,4,4,5,5,6,6,7,7,8,
9,10,11,12,13,14,15,16,18,20,21,23,25,28,30,33,36,39,43,47,51]
to record "ProgCalle" data;
set list [1,1,1,1,1,1,1,1,1,1,1,1] to record "ContCalles" data;
copy list [street(1-3),street(4-6),street(7-9),street(10-12),
street(13-15),street(16-18),street(19-21),street(22-24),
street(25-27),street(28-30),street(31-33),street(34-36)]
to record "TodasCalles" layout;

// Para Lineas
set list [1,1,1,1,1,2,2,2,3,3,4,5,6,7,8,10,12,14,17,21,25,30,36,43,52,
62,74,89,107,128] to record "ProgLinea" data;
set list [1,1,1,1,1,1,1,1,1,1,1] to record "ContLinea" data;
copy list [line(1-6),line(4-9),line(7-12),line(10-15),line(13-18),
line(16-21),line(19-24),line(22-27),line(25-30),
line(28-33),line(31-36)] to record "TodasLineas" layout;

// Para Cuadros
set list [1,1,1,1,1,1,1,1,2,2,2,2,3,3,3,4,4,5,5,6,7,8,9,10,11,12,14,16,
18,20,22,25,28,32,36,40,45,51,57,64,72,81,91]
to record "ProgCuadro" data;
set list [1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1]
to record "ContCuadro" data;
copy list [Corner(1:5),Corner(2:6),Corner(4:8),Corner(5:9),Corner(7:11),
Corner(8:12),Corner(10:14),Corner(11:15),Corner(13:17),
Corner(14:18),Corner(16:20),Corner(17:21),Corner(19:23),
Corner(20:24),Corner(22:26),Corner(23:27),Corner(25:29),
Corner(26:30),Corner(28:32),Corner(29:33),Corner(31:35),
Corner(32:36)] to record "TodosCuadros" layout;

//inicializo los contadores de las progresiones
put 1 en record "ProgDocCol" data index;
put 1 en record "ProgLinea" data index;
put 1 en record "ProgCalle" data index;
put 1 en record "ProgCuadro" data index;

//una pista a lo que son las triadas. no funcionando en esta version
copy list [number 2, split(9-12),split(10-13), number 20,
split(16-19),split(26-29),number 30,number 34]
to record "Triada A" layout;
copy list [number 3, number 1,number 11, split(15-18),split(21-24),
number 17,split(28-31),number 23,number 27]
to record "Triada B" layout;
copy list [number 6, split(5-8),split(4-7), number 14,split(22-25),
split(33-36),split(32-35)] to record "Triada C" layout;

//no funcional en esta version
Input Data "Enter your starting Bankroll" to Bankroll;

end
While on Each Spin
begin
// en Cada giro de bola

//llamo a metodos, son todos iguales en su estructura,
//lo que cambia son las variables de progresiones, contadores y layouts

call "buscar calle"
call "buscar Docena"
call "buscar Columna"
call "buscar Linea"
call "buscar Cuadro"

end
end

//el utilizar metodos es lo mas conveniente
//el primer Metodo expuesto, esta todo comentado
//pero es igual al resto que esta mas abajo
//lo unico que cambia entre cada uno de ellos, son:
//las progresiones (ProgDocCol,ProgCalles,ProgLineas,ProgCuadros)
//los contadores (ContCalles,ContDocena,ContColumna,ContCuadro,ContLinea)
//los layoutes (TodasCalles,TodasDocenas,TodasColumnas,TodasLineas,TodosCuadros)

method "buscar calle"
begin
//inicializo los contadores
////en este estan ubicadas todas las calles, ordenadamente
put 1 to record "TodasCalles" layout index
////en este estan ubicados los contadores de cada calle por separado
////(sirve para ubicarse en la progresion)
put 1 to record "ContCalles" data index

//este bucle analiza calle por calle. sin tener que tener un codigo largo
//lo que hace es utilizar el "TodasCalles"layout donde estan ubicadas
// todas las calles, y avanza una por una, (mediante el index)
loop until record "TodasCalles" layout index >12
begin

//se fija si la calle no salio hace 48 bolas
if record "TodasCalles" layout has NOT hit more 48
begin

//copio el indice de "TodasCalles" al indice de "ContCalles"
put 100% record "TodasCalles" layout index to record "ContCalles" data index

//"contCalles" tiene los contadores de cada calle por separado, si
//el contador esta en 1, la progresion comienza desde el primer valor
//este contador se aplica al indice de la progresion
put 100% record "ContCalles" data to record "ProgCalle" data index;

//Hago la apuesta de la calle correspondiente
put 100% de record "ProgCalle" data to record "TodasCalles" layout

//Aumento el contador de dicha calle, al ir aumentando, lo que hago
//es en realidad aumentar el indice de la progresion
//es para no utilizar muchas copias de la misma progresion
add 1 to record "ContCalles" data;
end

//sigo con la proxima Calle, para continuar el bucle
add 1 to record "TodasCalles" layout index
end

//Comienzo de nuevo, esta vez para ver si salio alguna de las calles apostadas

//inicializo para el bucle
put 1 to record "TodasCalles" layout index

//el mismo metodo que recien
loop until record "TodasCalles" layout index >12
begin

//me fijo si acaba de salir cual calle
if record "TodasCalles" layout has hit 1
begin

//copio el indice de "TodasCalles" al de "contCalles
put 100% record "TodasCalles" layout index to record "ContCalles" data index

//pongo en 1 el contador de dicha calle. si ya salio hay q volver a empezar
put 1 to record "ContCalles" data;
end

//sigo con la proxima Calle, para continuar el bucle
add 1 to record "TodasCalles" layout index;
end
end

method "buscar Docena"
begin
put 1 to record "TodasDocenas" layout index
put 1 to record "ContDocena" data index
loop until record "TodasDocenas" layout index >3
begin
if record "TodasDocenas" layout has NOT hit more 12
begin
put 100% record "TodasDocenas" layout index to record "ContDocena" data index
put 100% record "ContDocena" data to record "ProgDocCol" data index;
put 100% de record "ProgDocCol" data to record "TodasDocenas" layout
add 1 to record "ContDocena" data;
end
add 1 to record "TodasDocenas" layout index
end
put 1 to record "TodasDocenas" layout index
loop until record "TodasDocenas" layout index >3
begin
if record "TodasDocenas" layout has hit each
begin
put 100% record "TodasDocenas" layout index to record "ContDocena" data index
put 1 to record "ContDocena" data;
end
add 1 to record "TodasDocenas" layout index;
end
end

method "buscar Columna"
begin
put 1 to record "TodasColumnas" layout index
put 1 to record "ContColumna" data index
loop until record "TodasColumnas" layout index >3
begin
if record "TodasColumnas" layout has NOT hit more 12
begin
put 100% record "TodasColumnas" layout index to record "ContColumna" data index
put 100% record "ContColumna" data to record "ProgDocCol" data index;
put 100% de record "ProgDocCol" data to record "TodasColumnas" layout
add 1 to record "ContColumna" data;
end
add 1 to record "TodasColumnas" layout index
end
put 1 to record "TodasColumnas" layout index
loop until record "TodasColumnas" layout index >3
begin
if record "TodasColumnas" layout has hit each
begin
put 100% record "TodasColumnas" layout index to record "ContColumna" data index
put 1 to record "ContColumna" data;
end
add 1 to record "TodasColumnas" layout index;
end
end

method "buscar Linea"
begin
put 1 to record "TodasLineas" layout index
put 1 to record "ContLinea" data index
loop until record "TodasLineas" layout index >11
begin
if record "TodasLineas" layout has NOT hit more 32
begin
put 100% record "TodasLineas" layout index to record "ContLinea" data index
put 100% record "ContLinea" data to record "ProgLinea" data index;
put 100% de record "ProgLinea" data to record "TodasLineas" layout
add 1 to record "ContLinea" data;
end
add 1 to record "TodasLineas" layout index
end
put 1 to record "TodasLineas" layout index
loop until record "TodasLineas" layout index >11
begin
if record "TodasLineas" layout has hit each
begin
put 100% record "TodasLineas" layout index to record "ContLinea" data index
put 1 to record "ContLinea" data;
end
add 1 to record "TodasLineas" layout index;
end
end

method "buscar Cuadro"
begin
put 1 to record "TodosCuadros" layout index
put 1 to record "ContCuadro" data index
loop until record "TodosCuadros" layout index >22
begin
if record "TodosCuadros" layout has NOT hit more 36
begin
put 100% record "TodosCuadros" layout index to record "ContCuadro" data index
put 100% record "ContCuadro" data to record "ProgCuadro" data index;
put 100% de record "ProgCuadro" data to record "TodosCuadros" layout
add 1 to record "ContCuadro" data;
end
add 1 to record "TodosCuadros" layout index
end
put 1 to record "TodosCuadros" layout index
loop until record "TodosCuadros" layout index >22
begin
if record "TodosCuadros" layout has hit each
begin
put 100% record "TodosCuadros" layout index to record "ContCuadro" data index
put 1 to record "ContCuadro" data;
end
add 1 to record "TodosCuadros" layout index;
end
end